センサーで取得したデータをWiFiでスプレッドシートに送信するIoTセンサーを自作

var SS = SpreadsheetApp.openById('スプレッドシートのID');
var sheet = SS.getSheetByName('シート名');
var str = "";

function doPost(e) {

  var parsedData;
  var result = {};
  
  try { 
    parsedData = JSON.parse(e.postData.contents);
  } 
  catch(f){
    return ContentService.createTextOutput("Error in parsing request body: " + f.message);
  }
  if (parsedData !== undefined){  
    switch (parsedData.command) {
      case "appendRow":
         var dataArr = parsedData.values.split(",");
         var now = Utilities.formatDate(new Date(), "JST", "yyyy/MM/dd HH:mm:ss");
         dataArr.unshift(now);
         sheet.appendRow(dataArr);

         str = "Success";
         SpreadsheetApp.flush();
         break;     
    }
    return ContentService.createTextOutput(str);
  }

  else{
    return ContentService.createTextOutput("Error! Request body empty or in incorrect format.");
  }
}

#include <ESP8266WiFi.h>
#include <DebugMacros.h>
#include "HTTPSRedirect.h"

extern const char* ssid = "WiFiのSSID(ネットワーク名)を入力";
extern const char* password = "WiFiのパスワードを入力";
extern const char* host = "script.google.com";
extern const char *GScriptId = "デプロイIDを入力";

const int httpsPort = 443;

String url = String("/macros/s/") + GScriptId + "/exec";

String payload_prefix =  "{\"command\": \"appendRow\", \
                    \"sheet_name\": \"シート名を入力\", \
                    \"values\": ";

String payload = "";

HTTPSRedirect* client = nullptr;

void setup() {
  Serial.begin(115200);
  Serial.flush();

  Serial.println();
  Serial.print("Connecting to wifi: ");
  Serial.println(ssid);
  Serial.flush();

  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void loop() {
  static int error_count = 0;
  bool flag = false;

  client = new HTTPSRedirect(httpsPort);
  client->setInsecure();
  client->setPrintResponseBody(true);
  client->setContentTypeHeader("application/json");

  Serial.print("Connecting to ");
  Serial.println(host);

  // Try to connect for a maximum of 5 times
  for (int i = 0; i < 5; i++) {
    int retval = client->connect(host, httpsPort);
    if (retval == 1) {
      flag = true;
      break;
    }
    else
      Serial.println("Connection failed. Retrying...");
  }

  if (!flag) {
    delete client;
    Serial.print("Could not connect to server: ");
    Serial.println(host);
    Serial.println("Exiting...");
    ESP.deepSleep( 0 );
    delay( 1000 );
  }

  float vRatio = 0.32;
  int adcValue = analogRead(A0);
  int calValue = 0.946 * (adcValue - 13) / vRatio;

  payload = payload_prefix + "\"" +  calValue +  "\"}";

  if (client->POST(url, host, payload)) {
    Serial.println("data sent successfully");
  }
  else {
    error_count++;
    Serial.print("Error");
    Serial.println(error_count);
  }

  if (error_count > 3) {
    Serial.println("Halting processor...");
    delete client;
    client = nullptr;
    Serial.flush();
    ESP.deepSleep(0);
  }

  delete client;

  delay(60000);
}